Dr Logo 1

This is a simple logo program for anyone to copy and try out.

Firstly take your system discs (side 4) and put in A Drive of your PCW
or copy Dr Logo onto another disc to give you more room.  You can make it self booting with Submit.com, profile.eng and your J?.ems files.

Type in logo and when the screen clears to a ? type the following:-

ht (hide turtle) setsplit 1 (1-5) will give several lines at the bottom of the screen so you can read your text as you type it in and allow you to show more of each figure that you draw later on.

To circle
( > this prompt will come up) repeat 60 [fd 6 rt 6]
end

ht will sometimes only work after you have drawn your first figure and once it has been produced you can clear the screen with cs.

to square
repeat 4 [fd 100 rt 90]
end

to triangle
repeat 3 [fd 100 rt 120]
end

Type save "draw (or whatever you want to call it)

Now for the clever part!

Type copyon
     pops
and all three procedures will be sent to your printer  and you can study the method.  Copyoff switches off the printer and then you can log off by typing bye (Really user friendly).

Each time you want to add more you must save with a new title eg: Draw1, and check it by logging off with bye before erasing your first titled program by typing erasefile "draw.

You can then experiment with these commands before trying something more ambitious.  I will put more in each monthly newsletter and gradually you will grow more confident or you can send a disc to our Secretary who will be pleased if you include the postal charges to send it back with more programs on that I have developed so far.  I am still learning a lot about this relatively unknown part of the systems disc and will be grateful to anyone who can show me more.  

Chris 


Logo 2

Now we can look at more complicated figures.

Now type 

to star6
rt 30 fd 60
repeat 6 [rt 120 fd 60 lt 60 fd 60]
end

This will produce a six pointed star as I have calculated all the angles in advance.  Preferrably you could type in a more complicated routine:-

to staranysize :number :side
rt 30 fd :side
repeat :number [rt 180 - (360 / :number) fd :side lt 180 - (360 / :number) - (360 / :number) fd :side]
end

This introduces several variables and will allow you to increase the length of the sides of the star and the number of points but remember to make them divisible into 360 even if you make them something like 720 as this will leave a .5 of a degree for each point.  By trial and error you will find that too large a side will take your figure off the screen in places so compromise.

Now for something really special you can use a routine I copied from an old 8000 Plus magazine and called spiral.  

to spiral :number :side :increment :angle
label "overhere
fd :side
rt :angle
make "side (:side + :increment)
make "number (:number - 1)
if :number = 0 [stop]
go "overhere
end

Now when you type in this routine the first variable means the number of lines drawn and this will depend on the other variables as it could cover the whole screen very quickly, try 100 for this.  The next variable needs to be small too so try any number between 1 and 5 to start with but if you begin at 100 you will have an empty centre to the figure.  The third number will need to be smaller as it shows the amount of increase each time a line is drawn and after 100 times even 5 makes 500.  The last number is important as it must be similar to 120 for a triangular shape either 2-3 less or more, or 90 for a squarish shape, 60 for a pentagonal one etc.  Remember to add or substract one to three from each number.  Under will make the figure spiral one way and over will make it spiral the other way.
If you use numbers like 160 etc a many pointed star will show up.
If the angle is around 180 a wing shaped figure will be produced.

Remember to save it all by typing save "draw2 (or whatever you choose.)


Logo3

Now having played around with last month's figures you can try even more stranger commands.

If your circles are not round type setscrunch 0.5.  This command setscrunch can increase the number of pixels on the screen from 500 to 2500 and flatten an image in a quasi 3D effect.

Try setscrunch 0.1 or any variation up to 0.5.  Numbers over this will stretch the screen upwards and narrow it too and the highest level you can go to is setscrunch 10.  But this will make most figures go over the top quite literally.

Now for a special routine for a bit of fun.

to pond
pu bk 200 lt 90 fd 200 rt 90 pd
repeat 4 [fd 400 rt 90] pu home
end
to waterflea :dist
make "move random :dist
fd :move
check
rt random 360
waterflea :dist
end
to check
if xcor > 200 [oops]
if xcor < -200 [oops]
if ycor > 200 [oops]
if ycor < -200 [oops]
end
to ycor
op item 2 tf
end
to xcor
op item 1 tf
end
to oops
type char 7
bk :move
end

This will give you a square pond and the turtle arrow will move randomly the distance you have allowed it to until it crosses the pond when it will make a noise to show what has happened.  To make it run type waterflea 50 (or more). Remember to save "draw3 (or whatever).

By contacting the Secretary you can recieve a copy of all the commands I have found out so far, many of which I have not used and if you can pay the postage he will include the option to copy a disc with all the routines and a few more so you can try them out but remember to include your spare disc with the postage as we are a small club.


Logo4

Now for something special

to clock
seth :mh pe fd 70
pu home
make "mh :mh + 6
pd seth :mh fd 70
pu home
seth :hh pe fd 40
pu home
make "hh :hh + 0.5
pd seth :hh fd 40
pu home
delay 4420
end
to start
ht
setsplit 6
pu home pd
face
hands
repeat 720 [clock]
end
to face
cs repeat 12 [line]
end
to line
pu fd 80 pd
fd 40 pu bk 120
rt 30
end
to hands
pr [enter minute hand reading]
pr [then hit RETURN]
make "mh item 1 rl
make "mh :mh * 6 - 6
make "qq :mh / 360
pr [now the hour hand heading]
make "hh item 1 rl
make "tt :hh + :qq
make "hh :tt * 30
ct
end
to delay :tick
repeat :tick [pu pd]
end

Type start and then you will be asked to type in the minutes and hour settings and the clock hands will keep moving around in proper time if you wanted to leave it on you could have your own PCW clock!
Good Luck with your own routines.  Don't forget to save "draw4.

Regards Chris